利用vbs类实现css按钮,建议入精华

新客网 XKER.COM 2003-07-11 来源： 收藏本文

<%
rem 文章标题： 利用vbs类实现css按钮
rem 作者：yanek
rem 联系：aspboy@263.net

Class CssButton

  Public Name
  Public BackColor
  Public BorderColor
  Public Font
  Public FontColor
  Public Width
  Public Text
  Public Url

  Public MouseOverColor

    
  Public Function GenerateStyleTag()
    'Create the STYLE tag
    Dim strStyle
    strStyle =     "<STYLE TYPE=""text/css"">" & vbCrLf & _
                   "<!--" & vbCrLf & _
                   "#mybutton" & Name & "   {border-style: inset; " & vbCrLf & _
                   "             border-color: " & BorderColor & ";" & vbCrLf & _
                   "             background-color: " & BackColor & ";" & vbCrLf & _
                   "             width: " & Width & ";" & vbCrLf & _
                   "             text-align: center; }" & vbCrLf & vbCrLf & vbCrLf & _
                   "A.buttontext" & Name & " {color: " & FontColor & "; " & vbCrLf & _
                   "              text-decoration: none; " & vbCrLf & _
                   "              font: " & Font & ";" & vbCrLf & _
                   "              cursor: hand; }" & vbCrLf & vbCrLf & vbCrLf & _
                   ".buttonover" & Name & " {color: " & MouseOverColor & ";" & vbCrLf & _
                   "             text-decoration: none; " & vbCrLf & _
                   "             font: " & Font & ";" & vbCrLf & _
                   "             cursor: hand; }" & vbCrLf & _
                   " // -->" & vbCrLf & _
                   "</STYLE>"

    GenerateStyleTag = strStyle
  End Function


  Public Function GenerateButtonTag()
    Dim strHTML
    strHTML = "<a href=""" & Url & """ class=""buttontext" & Name & """ " & _
              "onMouseOver=""this.className='buttonover" & Name & "';"" " & _
              "onMouseOut=""this.className='buttontext" & Name & "';"">" & _
              vbCrLf & "<div id=""mybutton" & Name & """>" & vbCrLf & Text & vbCrLf & "</div></a>" & vbCrLf

    GenerateButtonTag = strHTML
  End Function

End Class

rem 建立类的实例

Dim btnYahoo, btnLycos
Set btnYahoo = New CssButton
Set btnLycos = New CssButton

rem 设置按钮对象的相关属性

btnYahoo.BackColor = "#aaaaaa"
btnYahoo.BorderColor = "#bbbbbb"
btnYahoo.Font = "bold 12pt Verdana"
btnYahoo.FontColor = "black"
btnYahoo.Width = "80px"
btnYahoo.MouseOverColor = "yellow"
btnYahoo.Url = "http://www.yahoo.com/"
btnYahoo.Name = "yahoo"
btnYahoo.Text = "Yahoo!"

rem 调用方法输出按钮
Response.Write btnYahoo.GenerateStyleTag()
Response.Write btnYahoo.GenerateButtonTag()
Response.Write "<p> </p>"



rem 设置按钮对象的相关属性
btnLycos.BackColor = "#aaaaaa"
btnLycos.BorderColor = "#bbbbbb"
btnLycos.Font = "10pt Arial"
btnLycos.FontColor = "black"
btnLycos.Width = "70px"
btnLycos.MouseOverColor = "yellow"
btnLycos.Url = "http://www.lycos.com/"
btnLycos.Name = "lycos"
btnLycos.Text = "Lycos"

rem 调用方法输出按钮
Response.Write btnLycos.GenerateStyleTag()
Response.Write btnLycos.GenerateButtonTag()
%>



演示：http://www.cnaspol.com/vbsclasscssbutton.asp

• ·ASP+ACCESS数据库中文乱码问题解决
• ·编程实例 字母+数字验证码程序
• ·ASP连接数据库错误解决办法新法
• ·初学:ASP内建对象Response
• ·ASP网站Server object error的解决办法
• ·ASP技巧：让Len,Left,Right函数识别中文
• ·把网页中的电话号码生成图片的ASP程序
• ·ASP如何实现IE地址栏参数的判断
• ·细化解析：ASP连接11种数据库语法集锦
• ·ASP实现网页打开任何类型文件都保存
• ·ASP代码直接增加、删除ACCESS表和字段
• ·ASP：判断访问是否来自搜索引擎的函数
• ·ASP技巧：禁用页面缓存的五种方法
• ·学习ASP关于与变量子类型相关的函数
• ·ASP开发中的(VBScript)类基础学习
• ·ASP访问Excel文件